build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.2'
    id 'io.spring.dependency-management' version '1.1.4'
    id 'org.ec4j.editorconfig' version '0.1.0'
    id 'checkstyle'
    id("com.palantir.docker") version "0.36.0"
}

docker {
    name "${project.group}/${project.name}:${project.version}"
    files jar.outputs.files
    buildArgs(['JAR_FILE': "${project.name}-${project.version}.jar"])
}

editorconfig {
    excludes = ['build']
}

check.dependsOn editorconfigCheck // checkstyle이 설정 되어 있을 시, editorconfigCheck 후 checkstyle 진행

checkstyle {
    maxWarnings = 0
    configFile = file("${rootDir}/config/naver-checkstyle-rules.xml")
    configProperties = ["suppressionFile": "${rootDir}/config/naver-checkstyle-suppressions.xml"]
    toolVersion = "8.42"
}

compileJava.options.encoding = 'UTF-8'
compileTestJava.options.encoding = 'UTF-8'

group = 'mejai'
//version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = '17'
}
jar {
    enabled = false
}
//for lombok config
configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.9.0'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-hibernate5-jakarta'

    implementation 'org.postgresql:postgresql:42.7.2'

    compileOnly 'org.projectlombok:lombok'
    annotationProcessor('org.projectlombok:lombok')

    // only apple silicon
    runtimeOnly 'io.netty:netty-resolver-dns-native-macos:4.1.104.Final:osx-aarch_64'

    // test
    testImplementation 'org.springframework.boot:spring-boot-starter-test' // includes JUnit 5
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.0'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.10.0'
    runtimeOnly 'com.h2database:h2'

    developmentOnly 'org.springframework.boot:spring-boot-devtools'

    // Querydsl 추가
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // mapstruct 추가
    implementation 'org.mapstruct:mapstruct:1.5.5.Final'
    annotationProcessor 'org.mapstruct:mapstruct-processor:1.5.5.Final'
    testAnnotationProcessor 'org.mapstruct:mapstruct-processor:1.5.5.Final' // if you are using mapstruct in test code

    // feign
    implementation 'org.springframework.cloud:spring-cloud-starter-openfeign:4.1.0'

    // retry
    implementation("org.springframework.retry:spring-retry")
    implementation("org.springframework:spring-aspects")

    // swagger
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.0.2'

    // sqs
    implementation platform("io.awspring.cloud:spring-cloud-aws-dependencies:3.0.1")
    implementation 'io.awspring.cloud:spring-cloud-aws-starter-sqs:3.2.0-M1'

    implementation 'io.hypersistence:hypersistence-utils-hibernate-63:3.8.3'
    implementation 'io.jsonwebtoken:jjwt:0.12.6'
}

tasks.named('test') {
    useJUnitPlatform()
}