build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.3.1'
        classpath 'org.ajoberstar:gradle-git:1.3.2'
    }
}
apply plugin: 'com.android.library'
android {
    compileSdkVersion 23
    buildToolsVersion '23.0.2'

    defaultConfig {
        minSdkVersion 9
        targetSdkVersion 23
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
    }
}

dependencies {
    compile "com.android.support:support-v4:23.1.1"
    compile 'com.android.support:support-annotations:23.1.1'
}

allprojects {
    version = VERSION_NAME
    group = GROUP

    repositories {
        mavenCentral()
    }
}

import org.ajoberstar.grgit.Grgit

project.ext.vlcAndroidSource = file('vlc-android')
project.ext.vlcSource = file('vlc-android/vlc')

task cloneVlcAndroid << {
    Grgit.clone(uri: 'https://code.videolan.org/videolan/vlc-android.git',
            dir: project.ext.vlcAndroidSource)
}

// Only clone once.
cloneVlcAndroid.onlyIf { !project.ext.vlcAndroidSource.exists() }

task updateVlcCheckout(dependsOn: 'cloneVlcAndroid') << {
    try {
        def repo = Grgit.open(project.ext.vlcSource)
        repo.pull(rebase: true)
    }
    catch (RuntimeException e) {
        logger.warn("Wasn't able to update checkout at " + project.ext.vlcSource + ": "
                + e.getClass() + " - " + e.getLocalizedMessage());
    }
}

// Don't update vlc checkout if it doesn't exist yet.
// This is the case when we're building for the first time.
updateVlcCheckout.onlyIf { project.ext.vlcSource.exists() }

task purgeOldJniLibs(type: Delete, dependsOn: 'updateVlcCheckout') {
    delete "src/main/jniLibs"
}

task purgeOldJava(type: Delete, dependsOn: 'purgeOldJniLibs') {
    delete "src/main/java"
}

task compileVlcArmv7a(type: Exec, dependsOn: 'purgeOldJava') {
    workingDir project.ext.vlcAndroidSource
    commandLine './compile.sh'
    args "-a", "armeabi-v7a"
    args "release" // Remove this to build a debug libvlc
    args "-l" // only build libvlc
}

task buildVlcArmv7a(type: Copy, dependsOn: 'compileVlcArmv7a') {
    from(vlcAndroidSource.getAbsolutePath() + '/libvlc/jni/libs/armeabi-v7a/')
    into('src/main/jniLibs/armeabi-v7a/')
    finalizedBy 'copyLibVlcFiles'
}

/*
task compileVlcArmv8a(type: Exec, dependsOn: 'purgeOldJava') {
    workingDir project.ext.vlcAndroidSource
    commandLine './compile.sh'
    args "-a", "arm64-v8a"
    args "release" // Remove this to build a debug libvlc
    args "-l" // only build libvlc
}

task buildVlcArmv8a(type: Copy, dependsOn: 'compileVlcArmv8a') {
    from(vlcAndroidSource.getAbsolutePath() + '/libvlc/jni/libs/arm64-v8a/')
    into('src/main/jniLibs/arm64-v8a/')
    finalizedBy 'copyLibVlcFiles'
}
*/

task compileVlcMips(type: Exec, dependsOn: 'purgeOldJava') {
    workingDir project.ext.vlcAndroidSource
    commandLine './compile.sh'
    args "-a", "mips"
    args "release" // Remove this to build a debug libvlc
    args "-l" // only build libvlc
}

task buildVlcMips(type: Copy, dependsOn: 'compileVlcMips') {
    from(vlcAndroidSource.getAbsolutePath() + '/libvlc/jni/libs/mips/')
    into('src/main/jniLibs/mips/')
    finalizedBy 'copyLibVlcFiles'
}

task compileVlcX86(type: Exec, dependsOn: 'purgeOldJava') {
    workingDir project.ext.vlcAndroidSource
    commandLine './compile.sh'
    args "-a", "x86"
    args "release" // Remove this to build a debug libvlc
    args "-l" // only build libvlc
}

task buildVlcX86(type: Copy, dependsOn: 'compileVlcX86') {
    from(vlcAndroidSource.getAbsolutePath() + '/libvlc/jni/libs/x86/')
    into('src/main/jniLibs/x86/')
    finalizedBy 'copyLibVlcFiles'
}

/*
task compileVlcX8664(type: Exec, dependsOn: 'purgeOldJava') {
    workingDir project.ext.vlcAndroidSource
    commandLine './compile.sh'
    args "-a", "x86_64"
    args "release" // Remove this to build a debug libvlc
    args "-l" // only build libvlc
}

task buildVlcX8664(type: Copy, dependsOn: 'compileVlcX8664') {
    from(vlcAndroidSource.getAbsolutePath() + '/libvlc/jni/libs/x86_64/')
    into('src/main/jniLibs/x86_64/')
    finalizedBy 'copyLibVlcFiles'
}
*/

task copyLibVlcFiles(type: Copy) {
    from(vlcAndroidSource.getAbsolutePath() + '/libvlc/src/')
    into('src/main/java')
}

task buildLibVlc() {
}

buildLibVlc.dependsOn {
    tasks.findAll { task -> task.name.startsWith('buildVlc') }
}

tasks.withType(Javadoc).all { enabled = false }

//upload aar to maven central with sonatype
apply from: 'https://raw.githubusercontent.com/chrisbanes/gradle-mvn-push/97de89785bdbf0bc0b380fb60851cabc552811dc/gradle-mvn-push.gradle'