build.gradle

plugins {
    id 'java'
    id "io.spring.dependency-management" version "1.0.10.RELEASE" apply false
    id "org.sonarqube" version "3.1" apply false
    id "jacoco"
    id "org.owasp.dependencycheck" version "6.0.3" apply false
    id 'org.springframework.boot' version '2.3.6.RELEASE' apply false
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

allprojects {
    group = 'br.com.mballoni'
    version = "0.0.1- ${hashNumber()}-SNAPSHOT"
    sourceCompatibility = '1.8'
}

static def hashNumber() {
    'git rev-parse --short HEAD'.execute().getText().trim()
}

subprojects {
    apply plugin: "java"
    apply plugin: "io.spring.dependency-management"
    apply plugin: "org.sonarqube"
    apply plugin: "jacoco"
    apply plugin: "org.owasp.dependencycheck"
    apply plugin: "maven"
    apply plugin: 'maven-publish'

    ext {
        set('springBootVersion', '2.3.6.RELEASE')
    }

    repositories {
        maven { url "https://repo.spring.io/libs-release" }
        mavenCentral()
        mavenLocal()
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
        }
    }

    sonarqube {
        properties {
            property "sonar.sourceEncoding", "UTF-8"
            property "sonar.projectName", "Toggle Boot"
        }
    }

    jacocoTestReport {
        reports {
            xml.enabled true
        }
    }
}

jar.enabled = false