publish-module.gradle

apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: 'org.jetbrains.dokka'

task androidSourcesJar(type: Jar) {
    archiveClassifier.set('sources')
    if (project.plugins.findPlugin("com.android.library")) {
        // For Android libraries
        from android.sourceSets.main.java.srcDirs
        from android.sourceSets.main.kotlin.srcDirs
    } else {
        // For pure Kotlin libraries, in case you have them
        from sourceSets.main.java.srcDirs
        from sourceSets.main.kotlin.srcDirs
    }
}

tasks.withType(dokkaHtmlPartial.getClass()).configureEach {
    pluginsMapConfiguration.set(
            ["org.jetbrains.dokka.base.DokkaBase": """{ "separateInheritedMembers": true}"""]
    )
}

task javadocJar(type: Jar, dependsOn: dokkaJavadoc) {
    archiveClassifier.set('javadoc')
    from dokkaJavadoc.outputDirectory
}

artifacts {
    archives androidSourcesJar
}

group = PUBLISH_GROUP_ID
version = PUBLISH_VERSION

afterEvaluate {
    publishing {
        publications {
            release(MavenPublication) {
                // The coordinates of the library, being set from variables that
                // we'll set up later
                groupId PUBLISH_GROUP_ID
                artifactId PUBLISH_ARTIFACT_ID
                version PUBLISH_VERSION

                // Two artifacts, the `aar` (or `jar`) and the sources
                if (project.plugins.findPlugin("com.android.library")) {
                    from components.findByName("android") ?: components.findByName("release")
                } else {
                    from components.java
                }

                artifact androidSourcesJar
                artifact javadocJar

              // Mostly self-explanatory metadata
              pom {
                    name = PUBLISH_ARTIFACT_ID
                    description = 'Android USB mass storage library with FAT32 support.'
                    url = 'https://github.com/magnusja/libaums'
                    licenses {
                        license {
                            name = 'The Apache Software License, Version 2.0'
                            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        }
                    }
                    developers {
                        developer {
                          id = 'magnusja'
                          name = 'Magnus Jahnen'
                          email = 'github@mgns.tech'
                        }
                        developer {
                          id = 'depau'
                          name = 'Davide Depau'
                          email = 'davide@depau.eu'
                        }
                        // TODO add all the others
                    }

                // Version control info - if you're using GitHub, follow the
                // format as seen here
                scm {
                        connection = 'scm:git:github.com/magnusja/libaums.git'
                        developerConnection = 'scm:git:ssh://github.com/magnusja/libaums.git'
                        url = 'https://github.com/magnusja/libaums/tree/main'
                    }
                }
            }
        }
    }
}

signing {
    useInMemoryPgpKeys(
            rootProject.ext["signing.key"],
            rootProject.ext["signing.password"],
    )
    sign publishing.publications
}