build.gradle

buildscript {
	repositories {
		jcenter()

		maven {
			url "http://files.minecraftforge.net/maven"
		}
	}

	dependencies {
		classpath "net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT"
		classpath "com.github.jengelman.gradle.plugins:shadow:2.0.0"
	}
}

apply plugin: "net.minecraftforge.gradle.forge"
apply plugin: "com.github.johnrengelman.shadow"

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

version = "1.12.2-1.8.2.4"
group = "com.therandomlabs.randomportals"
archivesBaseName = "randomportals"

repositories {
	maven {
		url "https://jitpack.io"
	}

	maven {
		url "https://minecraft.curseforge.com/api/maven"
	}

	mavenCentral()
}

dependencies {
	shadow "com.github.TheRandomLabs:RandomLib:1.12-SNAPSHOT"
	compile "com.github.TheRandomLabs:RandomLib:1.12-SNAPSHOT"
	shadow "blue.endless:jankson:1.2.0"
	compile "blue.endless:jankson:1.2.0"
	deobfCompile "randompatches:randompatches:1.12.2:1.22.0.0"
}

shadowJar {
	classifier = ""
	relocate "com.therandomlabs.randomlib", "com.therandomlabs.randomportals.repackage.com.therandomlabs.randomlib"
	relocate "blue.endless.jankson", "com.therandomlabs.randomportals.repackage.blue.endless.jankson"
	configurations = [project.configurations.shadow]
}

reobf {
	shadowJar {
		mappingType = "SEARGE"
	}
}

tasks.build.dependsOn reobfShadowJar

artifacts {
	archives shadowJar
}

minecraft {
	version = "1.12.2-14.23.5.2847"
	runDir = "run"
	mappings = "stable_39"

	replace "@VERSION@", project.version
	replace "@FINGERPRINT@", project.findProperty("signSHA1")
}

processResources {
	//Ensure this task is redone when the versions change
	inputs.property "version", project.version
	inputs.property "mcversion", project.minecraft.version

	//Replace version and mcversion in mcmod.info
	from(sourceSets.main.resources.srcDirs) {
		include "mcmod.info"
		expand "version": project.version, "mcversion": project.minecraft.version
	}
}

jar {
	manifest {
		attributes "FMLAT": "randomportals_at.cfg"
	}
}

task signJar(type: SignJar, dependsOn: reobfJar) {
	onlyIf {
		project.hasProperty("keyStore")
	}

	keyStore = project.findProperty("keyStore")
	alias = project.findProperty("keyStoreAlias")
	storePass = project.findProperty("keyStorePass")
	keyPass = project.findProperty("keyStoreKeyPass")
	inputFile = jar.archivePath
	outputFile = jar.archivePath
}

build.dependsOn signJar