build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    ext.kotlin_version = '1.6.21'
    ext.support_version = "1.2.1"
    repositories {
        google()
        jcenter()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

plugins {
    id("io.gitlab.arturbosch.detekt").version("1.22.0")
    id 'io.github.gradle-nexus.publish-plugin' version '1.3.0' apply false
}

detekt {
    input = files(rootProject.rootDir)
    config = files("$projectDir/detekt.yml")
    allRules = true
    buildUponDefaultConfig = true

    reports {
        html.enabled = true
        xml.enabled = true
        xml.destination = file("$buildDir/reports/detekt/detekt-checkstyle.xml")
        html.destination = file("$buildDir/reports/detekt/detekt-report.html")
    }
}

tasks.detekt.jvmTarget = "11"

allprojects {

    group = 'com.telefonica.androidlogger'
    if (System.getProperty("SNAPSHOT_VERSION") != null) {
        version = System.getProperty("SNAPSHOT_VERSION")+"-SNAPSHOT"
    } else {
        version = System.getProperty("LIBRARY_VERSION") ?: "undefined"
    }

    repositories {
        google()
        jcenter()
    }
}
apply from: "${rootProject.projectDir}/publish_maven_central.gradle"