Add ability to use a lib.nixosSystem system configuration (nixosConfigurations.<name>) as a NixOps deployment node configuration (nixopsConfigurations.<deployment>.<name>)

[PAI5REECHO]

This way I can use nixos-rebuild .. and/or nixops deploy .. without repeating myself

[roberth]

NixOps relies on the ability to add its own modules, containing such data as ip addresses, ssh keys, etc, whereas a nixosConfigurations.x is supposed to be a complete, final configuration.

nixosModules on the other hand represents the more flexible "input" to NixOS; just some modules. This is a lot like configuration.nix, which has always been a module and which you could imports into NixOps if you like.

So if you don't really need nixopsConfiguration, I would recommend to leave them out, but otherwise I would recommend is something like:

nixosModules.x = /* most of your config */;

nixosModules.xPhysical = /* the relevant bits from `nixops show-physical` */;

nixosConfigurations.x = { imports = [ self.nixosModules.x self.nixosModules.xPhysical ]; }

nixopsConfigurations.y = {
  x = { imports=  [ self.nixosModules.x ]; };
};

[pasqui23]

I did

{
    nixosConfigurations = builtins.mapAttrs
      (hostName: v: nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = {
          inherit inputs;
          name = hostName;
        };
        modules = [
          self.nixopsConfigurations.defaults
          n
          ({ lib, ... }: {
            options.deployment = lib.mkOption {
              type = lib.types.anything;
              default = { };
            };
            config.networking = { inherit hostName; };
          })
        ];
      })
      self.nixopsConfigurations.nodes;
}

[nixos-discourse]

This issue has been mentioned on NixOS Discourse. There might be relevant details there:

https://discourse.nixos.org/t/can-i-reuse-nixosconfigurations-foo-in-nixops/25243/1

[nixos-discourse]

This issue has been mentioned on NixOS Discourse. There might be relevant details there:

https://discourse.nixos.org/t/can-i-reuse-nixosconfigurations-foo-in-nixops/25243/2

[n8henrie]

I came up with a similar approach with some additional help / explanation from @roberth (thanks again) and posted it in the linked discussion. The key fact I needed to understand was that I can't go back from a fully configured nixosSystem to a module, so I needed to reconfigure my existing nixosConfigurations into nixosModules which could then be used as the basis for a nixosConfiguration or a nixopsConfiguration. The gist of it is:

let 
...
hosts = rec {
    myLocalMachine.system = "x86_64-linux";
    myRemoteMachine.system = "x86_64-linux";
    myLocalDarwinMachine.system = "aarch64-darwin";
}
match_system = regex: (nixpkgs-stable.lib.filterAttrs (_: host: with host; builtins.match regex system != null) hosts);
...
in {
...
nixosModules =
      builtins.mapAttrs
      (hostname: attrs: {inputs, ...}: {
        imports = [
          ({
            config,
            pkgs,
            ...
          }: {nixpkgs.overlays = default-overlays;})
          other-modules
          ./system-configs/${hostname}/configuration.nix
          home-manager.nixosModules.home-manager
          {
            home-manager = {
              useGlobalPkgs = true;
              useUserPackages = true;
              users.n8henrie = import ./home.nix;
            };
          }
        ];
      })
      (match_system ".*-linux$");

nixosConfigurations = builtins.mapAttrs (_: module:
      lib.nixosSystem {
        modules = [module];
      })
    self.nixosModules;

darwinConfigurations =
      builtins.mapAttrs
      (hostname: sys:
        with sys;
          darwin.lib.darwinSystem {
...
})
      (match_system ".*-darwin$");

nixopsConfigurations.default = {
      nixpkgs = nixpkgs-stable;
      network = {
        storage.legacy = {};
      };
      myRemoteMachine = {
        imports = [self.nixosModules.myRemoteMachine];
        deployment = {
          targetHost = "myRemoteMachine.domain.com";
          targetPort = 22;
        };
      };
    };
}